Wyo VB Lecture Notes

Objective #1: Write Boolean expressions.

• A Boolean expression evaluates to either True or False. Such an expression is often called a Boolean condition. (George Boole, a mathematician and logician in the early Twentieth Century, provided key knowledge to the logic and binary system that is used in modern computers.)
  
• You evaluate a Boolean expression just as an algebraic expression. Work left to right and follow the order of operations. Boolean conditions can use relational operators and logical operators.
  
• The relational operators (sometimes called comparison operators) are:
  
  

  >	greater than
  <	less than
  >=	greater than or equal to
  <=	less than or equal to
  =	equal to
  <>	not equal to

  
  
• When string values are compared with relational operators, VB compares the strings based on their character Unicode values (formerly known as ASCII values). The Unicode value of an uppercase 'A' is 65. The Unicode value of an uppercase 'B' is 66. Therefore, 'A' is considered to be less than 'B'. In fact, the word 'Apple' is considered to be less than the word 'Banana' since a character by character comparison is performed and the uppercase A in Apple is compared against the uppercase B in Banana. Look up "ASCII chart" or "Unicode chart" in Google or refer to the Unicode chart in our classroom for other character Unicode values.
  
  
• The logical operators (sometimes called Boolean operators) are:
  

  And......
  Or.......
  Not

• Use the following truth table to remember how to evaluate the logical operators.
  
  

  A	B	A And B	A Or B
  0	0	0	0
  0	1	0	1
  1	0	0	1
  1	1	1	1

  
  
  Notice that the And logical operation is similar to mathematical multiplication since 0 * 0 = 0, 0 * 1 = 0, etc.
  Notice that the Or logical operation is similar to mathematical addition since 0 + 0 = 0, 0 + 1 = 1, etc.
  
  
• Examples of Boolean expressions using relational and logical operators.
  
  Assume that x = 1 and y = 13
  

  (x > 0)          evaluates to True since x is greater than 0
  (x <> 1)          evaluates to False since x is not equal to 1
  ((x > 5) Or (y <= 20))          evaluates to True since y is less than or equal to 20 (even though x is not greater than 5)
  ((Not (x = 12)) And (y = 13))          evaluates to True since x is not equal to 12 and y is equal to 13

• There are other logical operators that work in Visual Basic logical expressions including Xor. The Xor operator is similar to the Or operator but only one (i.e. exactly one) of its two conditions can be True for the whole expression to be True.
  
  
• Often, it is necessary to use complicated, compound Boolean expressions to represent a real-life scenario in a computer program algorithm. A compound Boolean expression is simply a Boolean expression that contains an And or an Or to join to smaller Boolean expressions. Be careful to observe the order of operations that Visual Basic observes between arithmetic, relational, and logical operators.You may need to add parentheses to the expression.

• The following excerpt is taken from the online help found in Visual Basic.

  "When several operations occur in an expression, each part is evaluated and resolved in a predetermined order. That order is known as operator precedence. Parentheses can be used to override the order of precedence; that is, they are evaluated in the left to right order in which they appear. Arithmetic and logical operators are evaluated in the following order of precedence:
  

  Order of Operations of various kinds of operators in Visual Basic
  Arithmetic		Relational		Logical
  Exponentiation (^)		Equality		Not
  Negation (-)		Inequality (<>)		And
  Multiplication and division (*, /)		Less than (<)		Or
  Integer division (\)		Greater than (>)		Xor
  Modulus arithmetic (Mod)		Less than or Equal to (<=)		Eqv
  Addition and subtraction (+ and -)		Greater than or Equal to (>=)		Imp
  String concatenation (& or + in some situations )		Like
  		Is

The string concatenation operator is not an arithmetic operator, but in precedence it does fall after all arithmetic operators and before all comparison operators. Similarly, the Like operator, while equal in precedence to all comparison operators, is actually a pattern-matching operator. The Is operator is an object reference comparison operator. It does not compare objects or their values; it checks only to determine if two object references refer to the same object."

You probably will not have to use the Like, Is, Xor, Eqv, and Imp operators very often, however the information above may still be useful to you. Those operators will not be covered on tests or quizzes for this course.

Objective #2: Use If statements to ensure that certain statements are executed only when a given condition applies.

• The If statement (sometimes called an "If Then statement") is very useful to represent "what-if" type scenarios in a computer program's algorithm. The statement works in the same way that you would interpret an if-then scenario using the English language
• The first line of an If statement must start with the keyword If.
• The first line of an If statement must end with the keyword Then.
• One or more statements follow the If Then line. These statements are considered to be the body of the If statement.
• You must type End If as the very last line of the If statement.
• The Boolean expression between the If and the Then keywords is called the control expression. If the control expression evaluates to True, then Visual Basic will execute the statement(s) that follow. If the control expression is False, then Visual Basic ignores the body of the If statement.
• Example:
  
  If (x = 0) Then
       lblResult.Text = "x is 0"
  End If
  
  
• Note that the body of the If statement is indented to make it easier to read and logically understand.
• Parenthesis are not required to placed around an If statement's control expression but they add to the readability of the code and should be used.
• One line If statements can be used in VB if the If statement would only have one body statement as in
  
  If (x = 0) Then lblResult.Text = "x is 0"
  
  If the If statement has two or more body statements it must be typed out with the End If line coming at the end as in
  
  If (x = 0) Then
       lblResult.Text = "x is 0"
       MessageBox.Show("Goodbye")
  End If
  
  Mr. Minich discourages the use of one-line If statements and prefers that all If statements be typed out over multiple lines.
  
  
• A common mistake by novice programmers is to use an incorrect version of the If statement like the following:

  If (dblSideA = dblSideB = dblSideC) Then
          lblTypeOfTriangle.Text = "Equilateral"        
  End If

  The Boolean expression, dblSideA = dblSideB = dblSideC, in the If statement is illegal. That expression must be broken into two or more subexpressions and joined with the logical operator And.  The following statement is correct:

  If ((dblSideA = dblSideB) And (dblSideB = dblSideC)) Then
          lblTypeOfTriangle.Text = "Equilateral"
  End If
  

• You can nest an If statement inside of a For loop as in the following example which finds the sum of all the even numbers between 2 and 10
  
  intSum = 0
  
  For J = 2 To 10
     
      If (intSum Mod 2 = 0) Then
        intSum = intSum + J
      End If
  
  Next
  
  
  
• You can use an Exit For statement to break out of a For loop.
  
  intSum = 0
  
  For J = 0 To 100
      intSum = intSum + 1
     
      If (intSum > 3) Then
          Exit For
      End If
  
  Next
  
  in this loop, the loop immediately stops iterating when intSum reaches 4 even though J never reaches 100

Objective #3: Use If Else and If ElseIf statements to select which of two sequences of statements will be executed, depending on whether a given condition is TRUE or FALSE.

• The If Else statement can be used to represent a slightly more complicated scenario than the plain If statement. If the control expression after the If keyword is False, then the statement(s) after the Else keyword is executed. The statement(s) following the Else acts as a default.
• The keyword Else appears on a line by itself and is followed by one or more statements that execute if the If control expression is False.
• Do not forget to type the End If phrase as the last line of an If Else statement. If you forget to do this, it will probably cause a compile error or a logic error which programmers informally call a "dangling else error".
• Example:

  If (strLightStatus = "On") Then
       lblLight.Text = "The light is on."
  Else
       lblLight.Text = "The light is off."
  End if

• The If ElseIf statement can be used to represent even more complicated scenarios.
• The ElseIf keyword must be followed by a control expression (within parenthesis for readability) of its own and the keyword Then.
• Example:

  If (strTrafficLightStatus = "Red") Then
       lblLight.Text = "The light is red."
  ElseIf (strLightStatus = "Yellow") Then
       lblLight.Text = "The light is yellow."
  End If

• An Else case may also be used with an If ElseIf statement but it must appear below the ElseIf part. For example,
  
  If (strTrafficLightStatus = "Red") Then
       lblLight.Text = "The light is red."
  ElseIf (strLightStatus = "Yellow") Then
       lblLight.Text = "The light is yellow."
  Else
       lblLight.Text = "The light is green."
  End If
  
• You can use as many ElseIf cases as you need but they must be placed after the If case and above the Else case (if it is used). For example,
  
  If (dblGrade >= 90) Then
     lblGrade.Text = "A"
  ElseIf (dblGrade >= 80) Then
     lblGrade.Text = "B"
  ElseIf (dblGrade >= 70) Then
     lblGrade.Text = "C"
  ElseIf (dblGrade >= 60) Then
     lblGrade.Text = "D"
  Else
     lblGrade.Text = "F"
  End If
   
  Notice the necessary use of the >= (greater than or equal to) operator rather than the > (greater than) operator in the example above since a student who earns a grade of exactly 90% should receive an A.
  
  Visual Basic will evaluate the If ElseIf statement above starting with the If condition. As soon as one of the control expressions is determined to be TRUE, Visual Basic will execute the body statements of that portion of the If ElseIf statement and then skip over the remaining parts. That is, in the example above, Visual Basic would never display both an A and a B in lblGrade.Text.
  
  An experienced programmer however wisely uses the Else portion of an If ElseIf statement in order to make his or her program's logic even better and safer. In the following example, the programmer hopes that the Else portion would never execute but in case of a logic error elsewhere in his/her program, the Else portion will help him/her figure out where a bug occurs in the program.
  
  If (dblGrade >= 90) Then
     lblGrade.Text = "A"
  ElseIf (dblGrade>= 80) Then
     lblGrade.Text = "B"
  ElseIf (dblGrade>= 70) Then
     lblGrade.Text = "C"
  ElseIf (dblGrade>= 60) Then
     lblGrade.Text = "D"
  ElseIf (dblGrade>= 0) Then
     lblGrade.Text = "F"
  Else
     lblGrade.Text = "A logic error occurred causing dblGrade to be less than zero!"
  End If
  
  
• It is necessary to represent the real-life problem accurately in your pseudocode before you choose which of the three forms of the If statements to use in your code. If you are not careful, you will unnecessarily complicate your algorithm (perhaps with an unnecessary If ElseIf statement) or you will not fully portray the scenario that you meant to describe. The grade that you receive for a program will be affected by your choice (and arrangement) of If statements.
  
  
• It is possible and sometimes necessary to nest one If statement within another. An example of nested If statements follows:
  
  If (dblGrade >= 90) Then
  
      If (dblGrade >= 98) Then
          lblGrade.Text = "A+"
      Else
          lblGrade.Text = "A"
      End If
  
  ElseIf (dblGrade >= 80) Then
     lblGrade.Text = "B"
  Else
     lblGrade.Text = "You earned a C or less."
  End If
  
  Notice that a whole If Else statement is found within the If portion of the outer If ElseIf statement. Also notice that blank lines are placed above and below the inner If Else statement for increased readability.
  
  
• Do not unnecessarily complicate your program or decrease its readability by using nested If statements when you could have simply used a single If ElseIf statement.

Objective #4: Use the Mod operator to test divisibility.

• From your previous math education, you should be familiar with the following terms that relate to divisibility:
  
  • evenly divisible
    
    Example - 10 is evenly divisible by 2 because 10 divided by 2 leaves a zero remainder
    
    
  • common factor
    
    Example - 3 is a common factor of 12 and 24 since it is a factor of 12 (3 * 4 = 12) and it is a factor of 24 (3 * 8 = 24)
    
    
  • multiple
    
    Example - 20 is a multiple of 5 since 5 times 4 is 20
    
    
  • divisor
    
    Example - 6 is a divisor of 42 since it divides evenly into 42 (42 divided by 6 leaves a remainder of 0)
    
    
  • prime
    
    Example - 13 is prime since it has no divisors except for itself and 1
    
    
• The Mod operator in Visual Basic is often used to test whether or not two numbers are divisible. That is, to find out if one number is evenly divisible (with no remainder) by another number, you would use the Mod operator. Divide the two numbers and find the remainder. The remainder is the answer that the Mod operator returns. Some people call the Mod operator "the remainder function."
  
  Examples:
  

15 Mod 4 = 3    because 15 divided by 4 leaves a remainder of 3
24 Mod 5 = 4    because 24 divided by 5 leaves a remainder of 4
30 Mod 10 = 0     because 30 divided by 10 leaves a remainder of 0
8 Mod 8 = 0        because 8 divided by 8 leaves a remainder of 0
"any number" Mod 1 = 0        because any number divided by 1 leaves a remainder of 0
"any even number" Mod 2 = 0    because any even number divided by 2 leaves a remainder of 0
"any odd number" Mod 2 = 1    because any odd number divided by 2 leaves a remainder of 1

You could say that the rule is "when the Mod of two numbers is zero, then the first number is evenly divisible by the second number." Or, one could say that "when the Mod of two numbers is zero, then the first number is a multiple of the second number."

• When any even number is divided by two, the remainder is zero. When any odd number is divided by two, the remainder is one. To determine if the variable intNum is even or odd, you can use the following If statement
  
  If (intNum Mod 2 = 0) Then
     MessageBox.Show(Str(intNum) + " is even")
  Else If (intNum Mod 2 = 1) Then
     MessageBox.Show(Str(intNum) + " is odd")
  End If
  
  
• To determine if the variable intNum is prime or composite, you can use the following If statement
  
  If (intNum = 2 Or intNum = 3 Or intNum = 5 Or (intNum Mod 2 <> 0 And intNum Mod 3 <> 0 And intNum Mod 5 <> 0)) Then
     MessageBox.Show(Str(intNum) + " is prime")
  Else
     MessageBox.Show(Str(intNum) + " is not prime")
  End If
  
  Are the extra parentheses in the If statement necessary? This algorithm would work for any value of intNum up to 48. Do you know why?

Objective #5: Use Select Case statements for multiple selection.

• You will not be tested in this Visual Basic class on Select Case statements however this objective is included in the notes since you should at least be familiar with Select Case statements since they are used by many programmers. It is not necessary though to use Select Case statements since If Else If statements can be used to produce the same logic.
  
• When a programmer has more than 2 or 3 possible branches, it is more efficient to use a Select Case statement rather than an If Then statement or an If Else statement. Often a Select Case statement is used because it is easier to read and understand even though it could be replaced by an If Else If statement.
  
• Consider a situation in which the variable intGrade is equal to a whole number between or including 1 and 10. An example of a Select Case statement is:
  
  Select Case intGrade
      Case 10, 9
          lblOutput.Text = "A"
      Case 8
         lblOutput.Text = "B"
      Case 7
         lblOutput.Text = "C"
      Case 6
         lblOutput.Text = "D"
      Case Is <= 5
         lblOutput.Text = "F"
      Case Else
         lblOutput.Text = "intGrade must have a bad value"
  End Select
  
  Notice the use of the comma between the 10 and the 9 in the first Case. Also, notice that the keyword Is must be used in situations like "Case Is <= 5" above. Two or more statements can be placed in any case of the Select Case statement.
• A variable is listed after the keywords Select Case on the first line. This variable is called the control variable of the Select Case statement. Depending on the value of that control variable, the computer will perform the statements in one and only one of the branches under each Case statements. Each case determines a specific value or range of values that the variable could take on.
• Once VB determines which case applies given the value of the variable, it performs the statements in that Case section. Then, the rest of the Select Case statement is skipped over and the computer program continues with any code that follows the End Select line.
• While it is not required to specify Case Else as the last section of a Select Case statement, it is a wise idea since it can be used effectively for error-checking and input validation.
• It is considered to be good style to indent the body statements within each Case section.